ELE618 - Sistemas Elétricos Industriais

Instalações Elétricas - Ademaro A. M. B. Cotrim
Capítulo 2 - Conceitos fundamentais

Prof. Dr. Thales A. C. Maia

UFMG - DEE

Potência Elétrica

Equações

\(\begin{aligned} u &= \sqrt{2} U \text{sen}(\omega t) \\ i &= \sqrt{2} I \text{sen}(\omega t - \phi) \end{aligned}\)

\(\begin{aligned} p &= \sqrt{2} U \text{sen}(\omega t) \cdot \sqrt{2} I \text{sen}(\omega t - \phi) \\ &= \sqrt{2} U I \cos(\phi) - U I \cos(2 \omega t - \phi) \end{aligned}\)

\(\begin{aligned} p &= \underbrace{UI \cos \Phi (1 - \cos 2\omega t)}_{\text{(I)}} - \underbrace{UI \cos \Phi \cos 2\omega t}_{\text{(II)}} \end{aligned}\)

\(\begin{aligned} P &= U I \cos \phi \\ Q &= U I \text{sen} \phi \end{aligned}\)

\(\begin{aligned} p &= \underbrace{P ( 1 - \cos (2 \omega t))}_{\text{(I)}} - \underbrace{Q \text{sen} (2 \omega t)}_{\text{(II)}} \end{aligned}\)

A potência instantânea p é dividida em duas parcelas, (I) e (II). A primeira oscila em torno do mesmo valor médio, UI cos Φ, e nunca se torna negativa e a segunda apresenta valor médio nulo.

Fig. 1: Gráficos da tensão, da corrente e da potência instantâneas em um circuito monofásico (Cotrim, 2009)

Exemplo

Os valores na entrada de um circuito que alimenta uma carga elétrica monofásica são:

\[ \dot{U} = 200 \angle 30^\circ \text{ V} \quad \text{e} \quad \dot{I} = 10 \angle 60^\circ \text{ A} \]

Calcular:

A impedância da carga:

Código 
∠(ang) = cis(deg2rad(ang))
pol(z) = "$(round(abs(z), digits=4)) ∠ $(round(rad2deg(angle(z)), digits=2))°"

U = 200∠(30); I =  10∠(60); Z = U / I;

println("Z = $(round(Z, digits=2))")   # retangular
println("Z = ", pol(Z))                # polar
Z = 17.32 - 10.0im
Z = 20.0 ∠ -30.0°

A potência ativa:

Código 
using Printf
P = abs(U) * abs(I) * cos(angle(Z))
@printf("P = %.3f kW", P/1e3)
P = 1.732 kW

A potência reativa:

Código 
Q = abs(U) * abs(I) * sin(angle(Z))
@printf("Q = %.3f kVar", Q/1e3)
Q = -1.000 kVar

O fator de potência:

Código 
fp = cos(angle(Z))
@printf("fp = %.3f", fp)
fp = 0.866

(capacitivo ou adiantado)

Potência Ativa em Sistemas Trifásicos

Sistema equilibrado

Em um sistema trifásico equilibrado, as tensões de fase (\(v\)) e correntes de fase (\(i\)) estão defasadas em \(120^\circ\) no tempo:

Tensões instantâneas:

\(\begin{aligned} v_A &= \sqrt{2} U \cos(\omega t) \\ v_B &= \sqrt{2} U \cos(\omega t - 120^\circ) \\ v_C &= \sqrt{2} U \cos(\omega t + 120^\circ) \end{aligned}\)

Correntes instantâneas (com ângulo de carga \(\Phi\)):

\(\begin{aligned} i_A &= \sqrt{2} I \cos(\omega t - \Phi) \\ i_B &= \sqrt{2} I \cos(\omega t - 120^\circ - \Phi) \\ i_C &= \sqrt{2} I \cos(\omega t + 120^\circ - \Phi) \end{aligned}\)

Calculando a Potência por Fase

Multiplicando tensão e corrente (\(p = v \cdot i\)) e aplicando a identidade trigonométrica \(\cos(A)\cos(B) = \frac{1}{2}[\cos(A-B) + \cos(A+B)]\), obtemos:

\(\begin{aligned} p_A &= UI [ \cos(\Phi) + \cos(2\omega t - \Phi) ] \\ p_B &= UI [ \cos(\Phi) + \cos(2\omega t - 120^\circ - \Phi) ] \\ p_C &= UI [ \cos(\Phi) + \cos(2\omega t + 120^\circ - \Phi) ] \end{aligned}\)

Note que cada fase possui uma componente constante (potência ativa) e uma componente oscilatória (que flutua no dobro da frequência da rede).

A Soma do Sistema Trifásico

A potência instantânea total (\(p_T\)) é a soma das três fases: \(p_T = p_A + p_B + p_C\).

Somando os termos, agrupamos a parte constante e a parte oscilatória:

\[p_T = 3 UI \cos \Phi + UI \underbrace{[ \cos(2\omega t - \Phi) + \cos(2\omega t - \Phi - 120^\circ) + \cos(2\omega t - \Phi + 120^\circ) ]}_{\text{A soma de três ondas defasadas em } 120^\circ \text{ é ZERO}}\]

Como as componentes oscilatórias estão simetricamente defasadas, elas se anulam perfeitamente a cada instante de tempo. O resultado é um fluxo de potência puramente constante:

\[p_T = 3 UI \cos \Phi\]

Queda de tensão

Queda de Tensão em Circuito Monofásico

A Figura mostra um circuito monofásico e o seu diagrama fasorial. A queda de tensão do circuito é definida a partir da impedância equivalente da carga e pode ser construída no diagrama fasorial.
\({}^{1}\)r é a resistência CA por condutor, por unidade de comprimento, x a reatância indutiva por condutor.

Fig. 2: Diagrama de carga monofásica concentrada na extermidade do circuito e diagrama de fasores (Cotrim, 2009)

A queda de tensão pode ser dividida nas parcelas geradas pelas correntes responsáveis pelas potências ativa e reativa:

  1. Queda associada à Potência Ativa (P): Corrente ativa passando pela resistência.

\(\Delta U_{Ativa} = I \cdot R \cos\phi\)

  1. Queda associada à Potência Reativa (Q): Corrente reativa passando pela reatância.

\(\Delta U_{Reativa} = I \cdot X \sin\phi\)

Para permitir a soma algébrica direta dessas grandezas, é considerada a projeção vetorial de ambas as quedas sobre o mesmo eixo (o eixo da tensão de referência).

Somando as parcelas agora alinhadas:

\(\Delta U \approx \Delta U_{Ativa} + \Delta U_{Reativa}\)

\(\Delta U \approx (I \cdot R \cos\phi) + (I \cdot X \sin\phi)\)

Colocando a corrente (\(I\)) em evidência, chegamos à equação:

\(\Delta U \approx I \cdot (R \cos\phi + X \sin\phi)\)

No circuito anterior:

\(\Delta U \approx 2 l I (r \cos\phi + x \sin\phi)\)

Exemplo

Fig. 3

Código 
Ia = 2; la = 10; # A; m;
Ib = 5; lb = 25; # A; m;
Ic = 7; lc = 12; # A; m;
Id = 10; ld = 32; # A; m;
r = 4.5; x = 0; # Ω/km
cosϕ = 0.8

Zap = r*cosϕ;                                       @printf("Zap = %.2f V/A\n", Zap)
ΔU0a = 2 * (la * 1e-3) * (Ia + Ib + Ic + Id) * Zap; @printf("ΔU0a = %.2f V\n", ΔU0a)
ΔUab = 2 * (lb * 1e-3) * (Ib + Ic + Id) * Zap;      @printf("ΔUab = %.2f V\n", ΔUab)
ΔUbc = 2 * (lc * 1e-3) * (Ic + Id) * Zap;           @printf("ΔUbc = %.2f V\n", ΔUbc)
ΔUcd = 2 * (ld * 1e-3) * Id * Zap;                  @printf("ΔUcd = %.2f V\n", ΔUcd)
@printf("\nQueda de tensão total\n0D = %.2f V", (ΔU0a+ΔUab+ΔUbc+ΔUcd))
Zap = 3.60 V/A
ΔU0a = 1.73 V
ΔUab = 3.96 V
ΔUbc = 1.47 V
ΔUcd = 2.30 V

Queda de tensão total
0D = 9.46 V

Compensação de Energia Reativa

Por que Corrigir o Fator de Potência?

Cargas indutivas (motores, transformadores, reatores) absorvem potência reativa \(Q\) da fonte. Um capacitor em paralelo fornece parte (ou toda) essa potência reativa localmente — a fonte só precisa suprir a diferença.

  • Reduz a potência aparente \(S\) e a corrente de linha, para a mesma potência ativa \(P\) entregue.
  • Reduz perdas Joule e queda de tensão no circuito de alimentação.
  • Evita penalidades de faturamento por baixo fator de potência (indústrias com \(\cos\varphi < 0{,}92\) pagam multa da concessionária no Brasil).

\[ Q_{\text{capacitor}} = Q_{\text{original}} - Q_{\text{desejada}} = P\,(\tan\varphi_{\text{original}} - \tan\varphi_{\text{desejado}}) \]

Exemplo: Correção de FP em Circuito Industrial

Circuito trifásico, \(U=220\text{ V}\), com duas cargas equilibradas:

Carga \(P\) (kW) \(\cos\varphi\) (indutivo)
1 60 0,75
2 168 0,80

Deseja-se corrigir o fator de potência global para \(\cos\varphi'=0{,}90\) instalando um banco de capacitores.

Código 
P1, cosphi1 = 60.0, 0.75
P2, cosphi2 = 168.0, 0.80

Q1 = P1 * tan(acos(cosphi1))
Q2 = P2 * tan(acos(cosphi2))

P = P1 + P2
Q = Q1 + Q2
S = sqrt(P^2 + Q^2)
cosphi = P / S

println("Potência ativa total:   P = $(round(P, digits=1)) kW")
println("Potência reativa total: Q = $(round(Q, digits=1)) kvar")
println("Potência aparente total: S = $(round(S, digits=1)) kVA")
println("Fator de potência original: cos(φ) = $(round(cosphi, digits=3))")
Potência ativa total:   P = 228.0 kW
Potência reativa total: Q = 178.9 kvar
Potência aparente total: S = 289.8 kVA
Fator de potência original: cos(φ) = 0.787
Código 
cosphi_novo = 0.90

Q_novo = P * tan(acos(cosphi_novo))
S_novo = sqrt(P^2 + Q_novo^2)
Q_capacitor = Q - Q_novo

U = 220.0
I_antes = S*1000 / (sqrt(3)*U)
I_depois = S_novo*1000 / (sqrt(3)*U)

println("Potência do banco de capacitores: Q_c = $(round(Q_capacitor, digits=1)) kvar")
println("Nova potência aparente: S' = $(round(S_novo, digits=1)) kVA  (era $(round(S, digits=1)) kVA)")
println("Corrente antes:  $(round(I_antes, digits=0)) A")
println("Corrente depois: $(round(I_depois, digits=0)) A")
println("\nA correção 'libera' $(round(S - S_novo, digits=1)) kVA de capacidade no circuito de alimentação.")
Potência do banco de capacitores: Q_c = 68.5 kvar
Nova potência aparente: S' = 253.3 kVA  (era 289.8 kVA)
Corrente antes:  761.0 A
Corrente depois: 665.0 A

A correção 'libera' 36.5 kVA de capacidade no circuito de alimentação.

Componentes Simétricos

O Método de Fortescue

Apresentado por Charles Fortescue em 1918: qualquer sistema trifásico desequilibrado de fasores (tensões ou correntes) pode ser decomposto na soma de três sistemas trifásicos equilibrados:

  • Sequência positiva (1): mesma sequência de fases do sistema original (\(abc\)).
  • Sequência negativa (2): sequência invertida (\(acb\)).
  • Sequência zero (0): os três fasores em fase entre si (sem defasagem).

\[ \dot E_a = \dot E_{a0} + \dot E_{a1} + \dot E_{a2} \qquad \dot E_b = \dot E_{a0} + a^2\dot E_{a1} + a\dot E_{a2} \qquad \dot E_c = \dot E_{a0} + a\dot E_{a1} + a^2\dot E_{a2} \]

É a principal ferramenta para calcular curtos-circuitos assimétricos (fase-terra, bifásico) em sistemas trifásicos — assunto do Capítulo 10.

O Operador \(a\)

Rotaciona um fasor em \(120°\) no sentido anti-horário — o equivalente trifásico do operador \(j\) (que rotaciona \(90°\)):

\[ a = 1\angle 120° \qquad a^2 = 1\angle 240° \qquad a^3 = 1\angle 0° = 1 \]

  • \(1 + a + a^2 = 0\) — soma de três fasores unitários equilibrados é sempre nula.
  • \(a^4=a,\ a^5=a^2\) — as potências de \(a\) se repetem em ciclos de 3.

Decomposição em Componentes Simétricos

Dados os três fasores desequilibrados \(\dot E_a, \dot E_b, \dot E_c\) (ou correntes), os componentes de sequência da fase \(a\) são:

\[ \dot E_{a0} = \frac{1}{3}\left(\dot E_a + \dot E_b + \dot E_c\right) \tag{2.82}\]

\[ \dot E_{a1} = \frac{1}{3}\left(\dot E_a + a\dot E_b + a^2\dot E_c\right) \tag{2.83}\]

\[ \dot E_{a2} = \frac{1}{3}\left(\dot E_a + a^2\dot E_b + a\dot E_c\right) \tag{2.84}\]

Os componentes das fases \(b\) e \(c\) são obtidos girando os da fase \(a\) pelo operador \(a\) (expressões 2.78-2.80).

Exemplo: Decompondo Correntes Desequilibradas

Sistema trifásico desequilibrado de correntes:

\[ \dot I_a = 10\angle 30°\text{ A} \qquad \dot I_b = 30\angle{-}60°\text{ A} \qquad \dot I_c = 15\angle 145°\text{ A} \]

Vamos calcular os componentes de sequência da fase \(a\) e verificar a reconstrução.

Código 
deg(x) = x * pi/180

Ia = 10 * exp(im*deg(30))
Ib = 30 * exp(im*deg(-60))
Ic = 15 * exp(im*deg(145))

a = exp(im*deg(120))

Ia0 = (Ia + Ib + Ic) / 3
Ia1 = (Ia + a*Ib + a^2*Ic) / 3
Ia2 = (Ia + a^2*Ib + a*Ic) / 3

fasor(z) = "$(round(abs(z), digits=2)) ∠ $(round(rad2deg(angle(z)), digits=1))°"

println("I_a0 = ", fasor(Ia0), " A")
println("I_a1 = ", fasor(Ia1), " A")
println("I_a2 = ", fasor(Ia2), " A")

# Verificação: reconstrução deve devolver Ia original
Ia_reconstruida = Ia0 + Ia1 + Ia2
println("\nVerificação -- I_a reconstruída: ", fasor(Ia_reconstruida), " A  (original: ", fasor(Ia), " A)")
I_a0 = 5.6 ∠ -47.4° A
I_a1 = 17.58 ∠ 45.1° A
I_a2 = 8.24 ∠ -156.3° A

Verificação -- I_a reconstruída: 10.0 ∠ 30.0° A  (original: 10.0 ∠ 30.0° A)

Impedâncias de Sequência

Cada componente/circuito tem uma impedância própria para cada sequência: \(\dot Z_1\) (positiva), \(\dot Z_2\) (negativa), \(\dot Z_0\) (zero).

  • Em equipamentos estáticos (linhas, transformadores): \(\dot Z_1 = \dot Z_2\).
  • \(\dot Z_0\) só existe onde há retorno pelo neutro ou pela terra — e inclui \(3\dot Z_n\) (a impedância do neutro conta triplicada).
  • Em curto trifásico (equilibrado): só circula sequência positiva, \(\dot I_{a1}=\dot E_a/\dot Z_1\).
  • Em faltas assimétricas (fase-terra, bifásicas): as três sequências se combinam — é aqui que o método realmente se paga.

Valores por Unidade (pu)

Por que Usar pu?

O valor por unidade (pu) de uma grandeza é a razão entre seu valor real e um valor de referência (base) da mesma grandeza:

\[ g_{pu} = \frac{g}{g_B} \qquad g\% = 100\, g_{pu} \]

  • Simplifica cálculos de curto-circuito e de sistemas com vários níveis de tensão (transformadores).
  • A impedância de um transformador em pu é a mesma nos dois lados (AT e BT) — evita ficar refletindo impedâncias por \((U_1/U_2)^2\) manualmente.
  • Fabricantes já fornecem impedâncias de transformadores e máquinas em pu/porcentagem (na base de sua potência e tensão nominais).

Bases Fundamentais

Escolhidas \(S_B\) (potência) e \(U_B\) (tensão), as demais bases ficam determinadas:

Monofásico Trifásico
Corrente-base \(I_B = \dfrac{S_B\,(\text{kVA})}{U_B\,(\text{kV})}\) \(I_B = \dfrac{S_B\,(\text{kVA})}{\sqrt{3}\,U_B\,(\text{kV})}\)
Impedância-base \(Z_B = \dfrac{U_B(\text{kV})^2\times 10^3}{S_B\,(\text{kVA})}\) (mesma fórmula — \(U_B\) de linha, \(S_B\) trifásico)

\[ Z_{pu} = \frac{Z\,(\Omega)}{Z_B\,(\Omega)} \]

Exemplo: Sistema Monofásico em pu

Carga indutiva de \(100\text{ kVA}\), \(\cos\varphi=0{,}8\), tensão na carga \(200\text{ V}\), alimentada por uma linha de impedância \((0{,}024+j0{,}08)\,\Omega\). Bases adotadas: \(S_B=100\text{ kVA}\), \(U_B=200\text{ V}\).

Código 
S_B = 100e3    # VA
U_B = 200.0    # V

I_B = S_B / U_B
Z_B = U_B^2 / S_B

Z_linha = 0.024 + 0.08im
Z_linha_pu = Z_linha / Z_B

S_carga = 100e3
cosphi = 0.8
U_pu = 1.0   # tensão na carga é a própria base

println("Corrente-base:   I_B = $(round(I_B, digits=1)) A")
println("Impedância-base: Z_B = $(round(Z_B, digits=3)) Ω")
println("Impedância da linha em pu: $(round(Z_linha_pu, digits=3)) pu")

# Corrente pu (referência na tensão da carga, fp=0.8 indutivo -> atraso)
I_pu = 1.0 * exp(-im*acos(cosphi))
U_gerador_pu = U_pu + Z_linha_pu * I_pu

println("\nTensão no gerador (pu): $(round(abs(U_gerador_pu), digits=3)) ∠ $(round(rad2deg(angle(U_gerador_pu)), digits=1))°")
println("Tensão no gerador (V):  $(round(abs(U_gerador_pu)*U_B, digits=1)) V")
Corrente-base:   I_B = 500.0 A
Impedância-base: Z_B = 0.4 Ω
Impedância da linha em pu: 0.06 + 0.2im pu

Tensão no gerador (pu): 1.175 ∠ 6.1°
Tensão no gerador (V):  234.9 V

Mudança de Base

A impedância de um equipamento costuma vir em pu na base de sua própria potência/tensão nominal — é preciso converter para a base comum do estudo:

\[ Z_{pu,\,2} = Z_{pu,\,1}\left(\frac{S_{B2}}{S_{B1}}\right)\left(\frac{U_{B1}}{U_{B2}}\right)^2 \tag{2.117}\]

Exemplo: Mudança de Base

Uma impedância de \(5\,\Omega\), nas bases \(10\text{ kV}\) e \(15.000\text{ kVA}\). Qual seu valor pu nas bases \(15\text{ kV}\) e \(30.000\text{ kVA}\)?

Código 
Z = 5.0
S_B1, U_B1 = 15000.0, 10.0   # kVA, kV
S_B2, U_B2 = 30000.0, 15.0   # kVA, kV

Z_pu1 = Z * S_B1 / (U_B1^2 * 1e3)
println("Z_pu na base original: $(round(Z_pu1, digits=3)) pu")

Z_pu2 = Z_pu1 * (S_B2/S_B1) * (U_B1/U_B2)^2
println("Z_pu na nova base:     $(round(Z_pu2, digits=3)) pu")
Z_pu na base original: 0.75 pu
Z_pu na nova base:     0.667 pu

pu em Transformadores

Fato notável: para um transformador, a impedância em pu é a mesma vista do lado de alta ou de baixa tensão — desde que as bases de tensão em cada lado sigam a relação de transformação nominal.

  • Isso permite somar diretamente impedâncias pu de trafo e gerador em cascata, sem refletir ohms de um lado para o outro.
  • Para motores de indução e síncronos com \(\cos\varphi\approx0{,}8\), uma aproximação usual: \(S_{nom}\,(\text{kVA}) \approx P_{nom}\,(\text{CV ou HP})\).

Circuito RL

O Degrau CC (Componente Aperiódica)

Quando aplicamos uma tensão contínua (degrau) sobre um circuito RL, a corrente não salta instantaneamente. Devido à indutância, ela cresce de forma exponencial até atingir seu valor máximo, ditada pela constante de tempo \(\tau\).

Código 
using DifferentialEquations, Plots

# Parâmetros e constante de tempo
R = 1.0; L = 0.05; τ = L / R
Vm = 100.0; intervalo = (0.0, 5.5τ)

# EDO: Degrau CC
V_dc(t) = Vm * (t >= 0)
f_dc(i, p, t) = (V_dc(t) - R * i) / L
sol_dc = solve(ODEProblem(f_dc, 0.0, intervalo), Tsit5())

plot(sol_dc, title="Corrente CC: Carga Exponencial", label="i(t)",
      xlabel="Tempo (s)", ylabel="Corrente (A)", lw=2, color=:black,
      size=(650,350))

t_tau = [τ, 2τ, 3τ, 4τ, 5τ]
i_tau = sol_dc.(t_tau)  # interpola no ponto exato

scatter!(t_tau, i_tau, color=:red, markersize=5, label="")
annotate!([(t_tau[k], i_tau[k] + 4, text("$(k)τ", 9, :red)) for k in 1:5])
Fig. 4: Resposta ao degrau de um circuito RL.

Regime Permanente CA (Componente Periódica)

Se o circuito já estivesse operando com uma fonte senoidal, teríamos apenas a componente periódica. É a corrente CA natural, defasada da tensão pelo ângulo da impedância (\(\theta\)).

Código 
f = 60.0; ω = 2 * π * f; Z_mod = sqrt(R^2 + (ω*L)^2)
θ = atan(ω*L/R)
α = θ - π/2 # Ângulo do curto (Pior Caso)

Im = Vm / Z_mod
i_periodico(t) = Im * sin(ω * t + α - θ)

t_plot = range(intervalo..., length=500)
plot(t_plot, i_periodico.(t_plot), title="Regime CA (Componente Periódica)",
      label="Corrente Senoidal", xlabel="Tempo (s)", ylabel="Corrente (A)",
      lw=3, color=:black, ls=:solid)
Fig. 5: Regime permanente de uma corrente de 1° harmônico.

\(\begin{aligned} Ri + L\frac{di}{dt} &= u \\ u &= U_M \text{sen}(\omega t + \Psi) \\ Ri + L\frac{di}{dt} &= U_M \text{sen}(\omega t + \Psi) \end{aligned}\)

A solução

\(i = I_M \operatorname{sen}(\omega t + \Psi - \Phi) + A\, e^{-\frac{t}{\tau}}\)

Em \(t = 0\)

\(\begin{aligned} 0 &= I_M \operatorname{sen}(\Psi - \Phi) + A \\ A &= -I_M \operatorname{sen}(\Psi - \Phi) \\ \end{aligned}\)

Corrente Assimétrica em Circuito RL

A Figura mostra uma corrente totalmente assimétrica em um circuito em série RL, o que indica a presença de seus componentes periódico e aperiódico. O fechamento da chave S no circuito RL é um fenômeno semelhante a um curto-circuito em um sistema onde a resistência e reatância são constantes.

Fig. 6: Gráfico da corrente assimétrica em um circuito em série RL (Cotrim, 2009)

Corrente Assimétrica

Código 
V_ac(t) = Vm * sin(ω * t + α) * (t >= 0.0)
f_ac(i, p, t) = (V_ac(t) - R * i) / L
sol_ac = solve(ODEProblem(f_ac, 0.0, intervalo), Tsit5())

i_aperiodico(t) = -Im * sin(α - θ) * exp(-t/τ)
t_plot = range(intervalo[1], intervalo[2], length=500)
p2 = plot(t_plot, sol_ac.(t_plot), title="Corrente de Curto-Circuito (Assimetria)",
          label="Corrente Total (EDO)", lw=3, color=:red, xlabel="Tempo (s)")

plot!(p2, t_plot, i_periodico.(t_plot), label="Comp. Periódica", ls=:dash,
      color=:black)
plot!(p2, t_plot, i_aperiodico.(t_plot), label="Comp. Aperiódica", ls=:dot, lw=3,
      color=:green)
Fig. 7: Exemplo da corrente assimétrica em um circuito em série RL

Abertura do disjuntor

Qual o comportamento ao abrir o disjuntor?

Código 
R_arc = 10.0  # resistência do arco (maior que R nominal, mas não infinita)

V_on(t)  = (t >= 0.0) * (t <= 5.5τ)
R_eff(t) = V_on(t) * R + (1 - V_on(t)) * R_arc
V_eff(t) = Vm * sin(ω * t + α) * V_on(t)

f_ac_break(i, p, t) = (V_eff(t) - R_eff(t) * i) / L


sol_ac = solve(ODEProblem(f_ac_break, 0.0, 2*intervalo[2]), Tsit5())

i_aperiodico(t) = -Im * sin(α - θ) * exp(-t/τ)

t_plot = range(intervalo[1], 1.2 * intervalo[2], length=500)
p2 = plot(t_plot, sol_ac.(t_plot), title="Corrente de Curto-Circuito (Assimetria)",
          label="Corrente Total (EDO)", lw=3, color=:red, xlabel="Tempo (s)")

plot!(p2, t_plot, i_periodico.(t_plot), label="Comp. Periódica", ls=:dash,
      color=:black)
plot!(p2, t_plot, i_aperiodico.(t_plot), label="Comp. Aperiódica", ls=:dot, lw=3,
      color=:green)
Fig. 8: Abertura do disjuntor

Abertura do disjuntor após o curto

Como fica a dinâmica do sistema?

Código 
# Tempos
t_curto    = 5.5τ         # curto começa após 3 ciclos
t_abertura = t_curto + 6/f # disjuntor abre 6 ciclos depois

# Resistências
R_carga = R;   L_carga = L
R_curto = 0.5; L_curto = 0.01; R_arc   = 10.0
L_eff(t) = t < t_curto ? L_carga : (t < t_abertura ? L_curto : L_carga)
R_eff(t) = 
      if t < t_curto
            R_carga
      elseif t < t_abertura
            R_curto
      else
            R_arc
      end

# Tensão: presente até a abertura, zero depois
V_eff(t) = Vm * sin(ω * t + α) * (t >= 0) * (t < t_abertura)
f_curto(i, p, t) = (V_eff(t) - R_eff(t) * i) / L_eff(t)


# t_fim = t_abertura + 3/f
# sol_ac = solve(ODEProblem(f_curto, 0.0, t_fim), Tsit5())


sol_ac = solve(ODEProblem(f_curto, 0.0, 2*intervalo[2]), Tsit5())

i_aperiodico(t) = -Im * sin(α - θ) * exp(-t/τ)

t_plot = range(intervalo[1], 1.5 * intervalo[2], length=500)
p2 = plot(t_plot, sol_ac.(t_plot), title="Corrente de Curto-Circuito (Assimetria)",
          label="Corrente Total (EDO)", lw=3, color=:red, xlabel="Tempo (s)")

plot!(p2, t_plot, i_periodico.(t_plot), label="Comp. Periódica", ls=:dash,
      color=:black)
plot!(p2, t_plot, i_aperiodico.(t_plot), label="Comp. Aperiódica", ls=:dot, lw=3,
      color=:green)
Fig. 9: Abertura do disjuntor

Transformador de Dois Enrolamentos

O transformador elementar de dois enrolamentos, alimentando uma carga, opera transferindo energia do circuito primário para o secundário. A figura apresenta o diagrama básico para a análise do transformador ideal.

Fig. 10: Diagrama de um transformador de dois enrolamentos (Cotrim, 2009)

Referências

COTRIM, Ademaro A. M. B. Instalações Elétricas. 5ª Edição. São Paulo: Pearson Prentice Hall, 2009.

Exercícios

Exercício 1

Calcule as potências aparente, ativa e reativa de uma carga monofásica com uma tensão e correntes de \(U = 220 \angle 0^\circ\) V e \(I = 10 \angle 30^\circ\) A

Código 
V = 220 * cis(0)             # 220∠0°
I = 10 * cis(30 * π / 180)   # 10∠30°

S = V * conj(I)              # potência aparente complexa
P = real(S)                  # ativa [W]
Q = imag(S)                  # reativa [VAr]

println("S = ", round(abs(S), digits=2), " VA")
println("P = ", round(P, digits=2), " W")
println("Q = ", round(Q, digits=2), " VAr")
S = 2200.0 VA
P = 1905.26 W
Q = -1100.0 VAr

Exercício 2

Uma carga trifásica ligada em estrela tem impedâncias iguais de \(10 + j10 \,\Omega\) por fase. Com uma tensão de linha de 220 V, quais são as potências ativa e reativa da carga?

Código 
V_L = 220; Z_fase = 10 + 10im

V_fase = V_L / sqrt(3); I_fase = V_fase / Z_fase

S_3phi = 3 * V_fase * conj(I_fase)
P = real(S_3phi); Q = imag(S_3phi)

println("Potência Ativa (P): ", round(P, digits=2), " W")
println("Potência Reativa (Q): ", round(Q, digits=2), " VAr")
Potência Ativa (P): 2420.0 W
Potência Reativa (Q): 2420.0 VAr

Exercício 3

Dado um circuito monofásico com três cargas (O-A: 10m, A-B: 15m, B-C: 20m; \(I_A=10\) A, \(I_B=20\) A, \(I_C=30\) A). Determinar as quedas de tensão em cada trecho e a total.

(Considere \(r = 4,5 \,\Omega/\text{km}\), \(x = 0\) e \(\cos\phi = 0,8\) indutivo para todas as cargas)

Código 
r = 4.5; cos_phi = 0.8; 
k_r = r * cos_phi

I_A = 10; I_B = 20; I_C = 30
l_OA = 10; l_AB = 15; l_BC = 20 # em metros

# Correntes nos trechos
I_OA = I_A + I_B + I_C
I_AB = I_B + I_C
I_BC = I_C

# Quedas de tensão (fator 2 para circuito monofásico)
dU_OA = 2 * (l_OA / 1000) * I_OA * k_r
dU_AB = 2 * (l_AB / 1000) * I_AB * k_r
dU_BC = 2 * (l_BC / 1000) * I_BC * k_r
dU_total = dU_OA + dU_AB + dU_BC

println("ΔU OA: ", round(dU_OA, digits=2), " V")
println("ΔU AB: ", round(dU_AB, digits=2), " V")
println("ΔU BC: ", round(dU_BC, digits=2), " V")
println("ΔU Total: ", round(dU_total, digits=2), " V")
ΔU OA: 4.32 V
ΔU AB: 5.4 V
ΔU BC: 4.32 V
ΔU Total: 14.04 V

Exercício 4

Dada uma carga trifásica com potência ativa de 50 kW e reativa de 50 kVAr indutiva, determine a potência do banco de capacitores para corrigir o fator de potência para 0,92.

Código 
P = 50 # kW
Q_atual = 50 # kVAr

fp_desejado = 0.92
phi_novo = acos(fp_desejado)
Q_novo = P * tan(phi_novo)
Q_banco = Q_atual - Q_novo
println("Potência do banco de capacitores: ", round(Q_banco, digits=2), " kVAr")
Potência do banco de capacitores: 28.7 kVAr

Exercício 5

Determinem as componentes simétricas das seguintes correntes: \(I_a = 20 \angle 90^\circ\) A, \(I_b = 20 \angle 90^\circ\) A e \(I_c = 0\) A.

Código 
Ia = 20 * exp(im * pi/2); Ib = 20 * exp(im * pi/2); Ic = 0.0 + 0.0im

a = exp(im * 2*pi/3)
I0 = (Ia + Ib + Ic) / 3
I1 = (Ia + a * Ib + a^2 * Ic) / 3
I2 = (Ia + a^2 * Ib + a * Ic) / 3

println("I0: ", round(abs(I0), digits=2), " ∠ ", round(rad2deg(angle(I0)), digits=1), "° A")
println("I1: ", round(abs(I1), digits=2), " ∠ ", round(rad2deg(angle(I1)), digits=1), "° A")
println("I2: ", round(abs(I2), digits=2), " ∠ ", round(rad2deg(angle(I2)), digits=1), "° A")
I0: 13.33 ∠ 90.0° A
I1: 6.67 ∠ 150.0° A
I2: 6.67 ∠ 30.0° A

Exercício 6

Para uma carga trifásica em delta com \(Z_{ab} = 10\,\Omega\), \(Z_{bc} = 10\angle 90^\circ\,\Omega\) e \(Z_{ca} = 10\angle -90^\circ\,\Omega\) e tensões \(V_{ab} = 220\angle 0^\circ\) V, \(V_{bc} = 220\angle -120^\circ\) V e \(V_{ca} = 220\angle 120^\circ\) V, determine as correntes de linha e as componentes simétricas.

Código 
Vab = 220 * exp(0im); Vbc = 220 * exp(-im * 120 * pi/180); Vca = 220 * exp(im * 120 * pi/180)
Zab = 10.0 + 0im; Zbc = 10 * exp(im * 90 * pi/180); Zca = 10 * exp(-im * 90 * pi/180)

# Correntes de fase
Iab = Vab / Zab; Ibc = Vbc / Zbc; Ica = Vca / Zca

# Correntes de linha
Ia = Iab - Ica; Ib = Ibc - Iab; Ic = Ica - Ibc

println("Ia: ", round(abs(Ia), digits=2), " ∠ ", round(rad2deg(angle(Ia)), digits=1), "° A")
println("Ib: ", round(abs(Ib), digits=2), " ∠ ", round(rad2deg(angle(Ib)), digits=1), "° A")
println("Ic: ", round(abs(Ic), digits=2), " ∠ ", round(rad2deg(angle(Ic)), digits=1), "° A")

# Componentes simétricas da corrente Ia
a = exp(im * 2*pi/3)
I0 = (Ia + Ib + Ic) / 3
I1 = (Ia + a * Ib + a^2 * Ic) / 3
I2 = (Ia + a^2 * Ib + a * Ic) / 3
println("I0: ", round(abs(I0), digits=2), " A")
println("I1: ", round(abs(I1), digits=2), " ∠ ", round(rad2deg(angle(I1)), digits=1), "° A")
println("I2: ", round(abs(I2), digits=2), " ∠ ", round(rad2deg(angle(I2)), digits=1), "° A")
Ia: 42.5 ∠ 15.0° A
Ib: 42.5 ∠ 165.0° A
Ic: 22.0 ∠ -90.0° A
I0: 0.0 A
I1: 12.7 ∠ -30.0° A
I2: 34.7 ∠ 30.0° A

Exercício 7

Qual é o valor real da impedância de um gerador monofásico de 20% cuja potência nominal é de 10 kVA e tem tensão de 220 V?

Código 
S_base = 10e3
V_base = 220
Z_pu = 0.20

Z_base = V_base^2 / S_base
Z_real = Z_pu * Z_base

println("Z_base = ", round(Z_base, digits=2), " Ω")
println("Z_real = ", round(Z_real, digits=2), " Ω")
Z_base = 4.84 Ω
Z_real = 0.97 Ω

Exercício 8

Qual é o novo valor da impedância em pu de 5% (0,05 pu) representada nas bases 13,8 kV e 30 MVA, se representada nas novas bases de 138 kV e 60 MVA?

\(\begin{aligned} Z &= Z_{pu,old} Z_{base,old} \\ Z &= Z_{pu,new} Z_{base,new} \\ Z_{pu,new} &= Z_{pu,old} \frac{Z_{base,old}}{Z_{base,new}} \\ \end{aligned}\)

Código 
Z_pu_velho = 0.05
V_base_velho = 13.8e3; S_base_velho = 30e6
V_base_novo = 138e3; S_base_novo = 60e6

Z_pu_novo = Z_pu_velho * (V_base_velho / V_base_novo)^2 * (S_base_novo / S_base_velho)

println("Novo Z_pu = ", round(Z_pu_novo, digits=5), " pu")
Novo Z_pu = 0.001 pu

Exercício 9

Gerador (20 MVA, 13,8 kV, X=30%) e Trafo (20 MVA, 13,8/138 kV, X=10%). Determine a tensão do gerador em pu, quando uma carga de 15 MVA com FP 0,8 indutivo sob 138 kV for ligada no secundário do trafo.

Código 
# Bases do sistema (vamos adotar as do gerador/trafo)
S_base = 20e6
V_base_sec = 138e3

X_trafo_pu = 0.10im

# Carga ligada no secundário (138 kV, portanto V_carga = 1.0 pu)
V_carga_pu = 1.0 + 0im
S_carga = 15e6
fp_carga = 0.8

# S_carga_pu = (15 / 20) = 0.75 pu
# S = P + jQ = S_mag * (cos(phi) + j sin(phi))
S_carga_pu_mag = S_carga / S_base; @show S_carga_pu_mag
P_carga_pu = S_carga_pu_mag * fp_carga; @show P_carga_pu
Q_carga_pu = S_carga_pu_mag * sin(acos(fp_carga)); @show Q_carga_pu
S_carga_pu_complex = P_carga_pu + im * Q_carga_pu; @show S_carga_pu_complex

# I_carga_pu = conj(S_carga_pu / V_carga_pu)
I_carga_pu = conj(S_carga_pu_complex / V_carga_pu)

# Tensão nos terminais do gerador (antes da reatância do trafo)
# E_gerador = V_carga + I_carga * X_trafo
E_gerador_pu = V_carga_pu + I_carga_pu * X_trafo_pu; @show E_gerador_pu

println("Tensão do gerador = ", round(abs(E_gerador_pu), digits=4), " pu")
S_carga_pu_mag = 0.75
P_carga_pu = 0.6000000000000001
Q_carga_pu = 0.4499999999999999
S_carga_pu_complex = 0.6000000000000001 + 0.4499999999999999im
E_gerador_pu = 1.045 + 0.06000000000000001im
Tensão do gerador = 1.0467 pu

Exercício 10

Para medições do ensaio de curto-circuito de um trafo monofásico de 2.000 VA, tensões 200/100 V, determine a impedância série em pu. Dados do ensaio (no primário): P = 8 W, I = 10 A, U = 1 V.

Código 
S_base = 2000.0; V_base = 200.0; I_base = S_base / V_base; Z_base = V_base^2 / S_base;

V_cc = 1.0; I_cc = 10.0; P_cc = 8.0

Z_eq = V_cc / I_cc
R_eq = P_cc / I_cc^2
X_eq = sqrt(Z_eq^2 - R_eq^2)

R_pu = R_eq / Z_base; @show R_pu, R_eq
X_pu = X_eq / Z_base; @show X_pu, X_eq
Z_pu = Z_eq / Z_base; @show Z_pu, Z_eq

println("Z_pu (módulo) = ", round(Z_pu, digits=4), " pu")
println("Z_pu (complexo) = ", round(R_pu, digits=4), " + j", round(X_pu, digits=4), " pu")
(R_pu, R_eq) = (0.004, 0.08)
(X_pu, X_eq) = (0.0030000000000000005, 0.06000000000000001)
(Z_pu, Z_eq) = (0.005, 0.1)
Z_pu (módulo) = 0.005 pu
Z_pu (complexo) = 0.004 + j0.003 pu

Obrigado!

http://thalesmaia.com/